#include "colors.inc"
#include "textures.inc"
#include "stones.inc"

/* the letters */

height_field {
   gif "c:\temp\titleimg.gif"
   water_level 0.01
   texture {
      Stone13
      finish { phong 0.2 }
      scale 1/4
   }
   translate <-0.5, 0, -0.5>
   scale <358/191, 1/6, 1>
   rotate <-90, 0, 0>
   scale 1.2
   rotate <7.5, 0, 2.5>
}

/* the floor */

disc {
   <0, -1.5, 0>, y, 4
   pigment {
      checker color rgb <1, 1, 1> color rgb <0, 0, 0>
      scale 1/2
   }
}

#declare Eyeball =  sphere {
   <0, 0, 0>, 1
   texture {
      pigment {
         granite
         color_map {
            [0/2 color LightBlue]
            [1/2 color SteelBlue]
            [2/2 color LightBlue]
         }
         scale 1/3
         turbulence 0.2
         rotate <90, 0, 0>
      }
   }
   texture {
      pigment {
         wood
         color_map {
            [0.0 color Black]
            [0.225 color Black]
            [0.225 color Clear]
            [0.45  color Clear]
            [0.45  color White]
            [1.0 color White]
         }
         scale 2
      }
   }
}

object {
   Eyeball
   scale 1/3
   rotate <45, -45, 0>
   translate <-0.7, -0.7, 0>
}

/* the reflective box in the upper right */

box {
   <-0.25, -0.25, -0.25>, <0.25, 0.25, 0.25>
   texture { Silver2 }
   rotate <0, 45, 0>
   rotate <-55, 0, 0>
   translate <0.9, 0.7, 0>
}

/* sky sphere with sunrise texture */

sphere {
   <0, 0, 0>, 10000
   texture {
      pigment {
         radial
         color_map {
            [0.0 color rgb <1, 1, 1>]
            [0.5 color rgb <0.3, 0.6, 1>]
            [1.0 color rgb <1, 1, 1>]
         }
         frequency 12
         rotate <90, 0, 0>
      }
      finish {
         diffuse 0
         ambient 0.9
      }
   }
   texture {
      pigment {
         wood
         color_map {
            [0.0 color rgb <1, 1, 1>]
            [0.1 color rgb <1, 1, 1>]
            [0.25 color rgbf <1, 1, 1, 1>]
            [1.0 color rgbf <1, 1, 1, 1>]
         }
         scale 20000
      }
      finish {
         diffuse 0
         ambient 0.9
      }
   }
}

light_source { <50, 150, -500> color rgb <1.5, 1.5, 1.5> }

camera {
   location <0, 0, -2>
   look_at <0, 0.01, -0.5>
}