The Online POV-Ray Tutorial

/*
   X: -23, 23
   Y: 0, 45.4
   Z: -18, 16 (los tiradores sobresalen un poco mas)
*/

#declare Tabla = difference {
    superellipsoid {<.05, .05>}
    plane {y, 0.8}
    translate -0.8*y
    scale <23, 6, 16>
}

#declare Tirador = union {
    sphere {<0, 2.25, 0>, 1.25}
    cone {<0, 0, 0>, 1.25, <0, 2.25, 0>, 0}
    rotate -90*x
    scale .8
}

#declare Cajon = difference {
    superellipsoid {<.05, .05>}
    plane {y, 0.8}
    translate -0.8*y
    scale <20, 6, 6>
    rotate -90*x
}

#declare Cajon = union {
    object {Cajon}
    object {Tirador translate <-12, 0, -1.2>}
    object {Tirador translate <12, 0, -1.2>}
}

#declare Pata = cone {<0, 0, 0>, 1.25, <0, -13, 0>, .35}

#declare Mesilla = union {

    box {<-22, -15, -15>, <22, 15, -13.8>
        texture {T_Wood10 scale 10 rotate 89*y}
    }
    box {<-22, -15, 13.8>, <22, 15, 15>
        texture {T_Wood10 scale 10 rotate 89*y}
    }
    box {<-22, -15, -13.8>, <22, 15, 13.8>
        texture {T_Wood10 scale 10 translate <0, 20, 0>}
    }

    object {Tabla translate <0, 15, 0>
        texture {T_Wood10 scale 10 rotate 89*y}
    }
    object {Tabla rotate 180*z translate <0, -15, 0>
        texture {T_Wood10 scale 10 rotate 89*y}
    }

    object {Cajon translate <0, 7, -15>
        texture {T_Wood10 scale 10 rotate 89*y translate <0, 14, 0>}
    }
    object {Cajon translate <0, -7, -15>
        texture {T_Wood10 scale 10 rotate 89*y translate <0, -20, 0>}
    }

    object {Tirador translate <-12, 7, -16.2>
        texture {T_Wood10}
    }
    object {Tirador translate <-12, 7, -16.2>
        texture {T_Wood10}
    }

    object {Pata translate <-18, -16.2, -11>
        texture {T_Wood10 scale 6 rotate 89*y}
    }
    object {Pata translate <-18, -16.2, 11>
        texture {T_Wood10 scale 6 rotate 89*y}
    }
    object {Pata translate <18, -16.2, -11>
        texture {T_Wood10 scale 6 rotate 89*y}
    }
    object {Pata translate <18, -16.2, 11>
        texture {T_Wood10 scale 6 rotate 89*y}
    }

    translate <0, 29.2, 0>
}

Object Library

Main Page