Horrors of horrors, you are going to learn how to make your own data types! Well, not really. Your so-called 'data types' are actually just your own customised way of storing values, as you'll soon find out. Feeling curious? Well, read on!

What are user-defined types?

How do we implement User-Defined Types?

First, you can declare it in a normal var declaration, with the data type representing what you want it to store. We'll use a known example - the string type:

  var
    ASmallString: String(10);

You've learnt uses, const, and var right? Well, here's type! The type keyword can replace a data type with another name:

  type
    TenCharacters = String(10);

  var
    ASmallString: TenCharacters;

The different User-Types follow...

1. Arrays

  type
    GameGrid = array [1..32, 1..32] of integer;

  var
    Grid1: GameGrid;
    Grid2: array [1..32, 1..32] of integer;

  var
    Line: array[0..255] of integer;
    Table: array[0..255, 67..127] of char;
    Cube: array['A'..'Z', 1..10, 1..10] of real;

  begin
    Cube['S', 5, 5] := 70;
  end.

1: program ArrayCrazy;
2:
3:   type
4:     TTable = array [1..2, 1..5] of integer;
5:
6:   var
7:     Table: TTable;
8:     a, b: integer;
9:
10:  begin
11:    for a := 1 to 2 do
12:      for b := 1 to 5 do
13:        begin
14:          Writeln('Input value for ',a ,', ', b,' : ');
15:          Readln(Table[a, b]);
16:        end;
17:    for a := 1 to 2 do
18:      for b := 1 to 5 do
19:        Writeln('Value ', a, ', ', b, ' is ', Table[a, b]);
20:  end.

Input value for 1, 1 :
1
Input value for 1, 2 :
2
Input value for 1, 3 :
3
Input value for 1, 4 :
4
Input value for 1, 5 :
5
Input value for 2, 1 :
6
Input value for 2, 2 :
7
Input value for 2, 3 :
8
Input value for 2, 4 :
9
Input value for 2, 5 :
10
Value 1, 1 is 1
Value 1, 2 is 2
Value 1, 3 is 3
Value 1, 4 is 4
Value 1, 5 is 5
Value 2, 1 is 6
Value 2, 2 is 7
Value 2, 3 is 8
Value 2, 4 is 9
Value 2, 5 is 10

This program may look a little complex, but actually it's very simple. If you're having problems visualising, we suggest that you change the default colours under Options, Environment, Colors... to make the different elements of code clearer. Let's begin!

• Line 4 - This defines the type TTable
• Line 7 - Declaration of variable Table of type TTable
• Line 8 - Declares two counters, a and b
• Line 11 - This starts a loop for the X coordinate
• Line 12 - This starts a loop for the Y coordinate: notice that this is a for loop in a for loop, this loop must finish before the first loop can loop again. Programmers call these loops nested loops.
• Line 14 & 15 - Prints a message and inputs what you type into the array at the specified coordinates.
• Line 17 & 18 - Starts another nested loop.
• Line 19 - This time, the loop prints out the value of Table at the specified coordinates. Ta-da! The End!

2. Records

  type
    Student = record
      Name, Class: string;
      Height, Weight: integer;
    end;

  var
    Brat: Student;

  begin
    Brat.Name := 'Lee Yang Yang';
    Brat.Class := '1M';
    Brat.Height := 12;
    Brat.Weight := 6;
  end.

  begin
    { How many times do we type "Brat"? }
    Brat.Name := 'Lee Yang Yang';
    Brat.Class := '1M';
    Brat.Height := 12;
    Brat.Weight := 6;
  end.

  with Brat do
    begin
      Name := 'Lee Yang Yang';
      Class := '1M';
      Height := 12;
      Weight := 6;
    end;

1: program RecordingTime;
2:
3:   type
4:     Student = record
5:       Name, Class: string;
6:       Height, Weight: integer;
7:     end;
8:
9:   var
10:    TheBrat: Student;
11:
12:  begin
13:    { We first assign TheBrat values }
14:    TheBrat.Name := 'Augustus Gloop';
15:    TheBrat.Class := '5F';
16:    TheBrat.Height := 145;
17:    TheBrat.Weight := 67;
18:
19:    { Now we print them out! }
20:    with TheBrat do
21:      begin
22:        Writeln('Name: ', Name);
23:        Writeln('Class: ', Class);
24:        Writeln('Height: ', Height);
25:        Writeln('Weight: ', Weight);
26:      end;
27:  end.

Name: Augustus Gloop
Class: 5F
Height: 145
Weight: 67

This is a simple one. (Then again, I say that for all the programs, don't I?) What it does is to simply input some values into a record and print them out again. Here's the final breakdown:

• Line 4, 5, 6 - Defines type Student with Name, Class, Height, and Weight. (Bet you've seen this before!)
• Line 10 - Declares variable TheBrat as type Student.
• Line 14, 15, 16, 17 - Here, we gave TheBrat some values, the hard way. See how irritating repeated typing can be? Oooo... (That tingling sensation!)
• Line 20 - This with statement refers to record TheBrat
• Line 22, 23, 24, 25 - Finally, these lines print out the values of TheBrat the easy way. Ahh, see that we can leave out 'TheBrat' now? So relaxing! We're finished for now, so let's go on to type No. 3

3. Set Types

- Opps! Of all the data types, we still haven't introduced Boolean yet, haven't we? Well never mind, we'll explain it now. You see, a Boolean type is just a type which is either true or false. Thus, you can type things like 'aBoolean := a = b;' - if a is equal to b, aBoolean is true. Otherwise, it's not. That simple!

  type
    aSet = set of 1..255;
    aSet2 = set of Char;
    aSet3 = set of ( Alpha, Beta, Gamma );

- Wait a minute! Remember I said that a set can only 255 values? How come I can declare a set with type Char - (aSet2 = set of Char;)? Well, simple. If you look up the ASCII chart, you'll notice that there are exactly 255 characters available (minus the null chracter, of course.) What the set does is to use all those characters as 'Check-Boxes', see? Don't try this with integer or real though, there are just too many possible values.

The first way is very simple - you place the values you want to turn on inside square brackets and assign it to the set, like this:

  begin
    aSet := [1, 7, 10..12, 5];
    aSet2 := ['A', 'K', 'X'..'Z'];
    aSet3 := [Alpha];
  end.

The second method to assign values is to use set operators: +, -, *. Unlike the plus, minus, and multiply functions, these are the add, minus, and intersect values! What? Well, here are the three set operator rules:

1. Value C will only be on in (Set A + Set B) if C is on in either A or B
2. Value C will only be on in (Set A - Set B) if C is on in A but not in B
3. Value C will only be on in (Set A * Set B} if C is on in both A and B

  begin
    aSet := [1, 3, 5, 7];      { 1 3 5 7 }
    aSet := aSet + [2, 3, 5];  { 1 2 3 5 7 }
    aSet := aSet - [3, 5];     { 1 2 7 }
    aSet := aSet * [7];        { 7 }
  end.

The operator to use when testing if a value is on in a set is the in operator. For example, to test if the number 3 is turned on in aSet, you would type the following piece of code:

  begin
    if (3 in aSet) then
      Writeln('Omigosh! 3 is on!');
  end.

- Now, we realise that you might be confused about why the operator is called 'in' - why isn't it called 'on', 'check', or something like that? Well, it's all very simple. The analogy we used for sets is to use a bunch of Check-Boxes. However, Pascal uses the analogy of testing whether a value is inside the set or not. ( Now you know why it's called a set! ) A set just contains a list list of values and in tests if the value you gave it is in that list. Confused? Well, don't worry, you don't need to know this to use sets - what you need is just a lot of common sense!

1: program SetItUp;
2: 
3:   type
4:     TSet = set of 1..10;
5: 
6:   var
7:     i: integer;
8:     Numbers: TSet;
9: 
10:  begin
11:    Numbers := [3, 6, 8..10];
12:    for i := 1 to 10 do
13:      if (i in Numbers) then
14:        Writeln(i);
15:  end.

3
6
8
9
10

Simple program, simple explanation. In fact, this program probably needs no explanation at all! But still, let's be fair, okay?

• Line 4 - This line defines type TSet which is a set of 1 to 10
• Line 7 - This declares a counter variable
• Line 8 - The set, Numbers, is declared here
• Line 11 - Here, we assign for Numbers to have values 3, 6, 8, 9, 10 turned on
• Line 12 - A for loop starts looping the counter from 1 to 10
• Line 13 & 14 - Here, we test if the counter is turned on in Numbers. If it is, it executes Line 14, which prints out the counter. (You see how it works now?)

End of Day 8